Satgen 395  Mars Surveyor Track  by GM4IHJ   (BID SGEN395)   19 Oct 96

The Mars Global Surveyor Experiment is scheduled to launch from
Florida on 6th Nov 96. It should reach Mars in Sept 97 and go into
orbit around the planet. Early in its passage to Mars , roughly 20 or
30 days after launch , when about 6 million kms from the earth, it
will test one of its beacon transmitters. The initial signal will be
unmodulated carrier on a frequency of 437.1 Mhz + or - doppler, at a
power level of 1.3 watts to a low gain antenna wired RHCP. Radio
Amateurs who have high gain antennas, low noise receivers and DSP
hardware or software are encouraged to try to locate the signal and
report its doppler, spin and fade characteristics.
The easiest way to find the beacon will be to translate the probes
published Right Ascension And Declination ( = Sky location) into
Azimuth and Elevation from your station. The following simple BASIC
program may assist those who do not presently have software for RaDec
to AzEl conversion. The program listing contains rem statements for a
worked example to assist in software checking. Use this first then
alter lines 30 and 40 with details of your stations Lat and, Long West
20 CLS:LET P1=3.141593:LET RCN=180/P1
30 LAT=56.125:REM change this to your Station latitude , -ve if south
40 LONG=3.6:REM change this to your station longitude west
50 LOCATE 5,5:INPUT"Time of Day UTC in HHMM ";TD:LET TD=TD/100
60 LOCATE 7,5:INPUT "Day of month           ";DE:REM DE=12 at 1220 utc
70 LOCATE 9,5: INPUT"Month number           ";MB:REM MB=10
80 LOCATE 11,5:INPUT"Fullyear number eg 1996";YA:REM YA=1996
90 LOCATE 13,5:INPUT"Right Asc hour.decimal hour ";VA:REM VA=5.525
100 LOCATE 15,5:INPUT"Dec degs.degs -ve if south  ";VB:REM VB=21.98
110 LET DE=DE+(INT(TD))/24 +(TD-(INT(TD)))*100/1440
120 IF MB<=2 THEN LET YA=YA-1:LET MB=MB+12
130 LET AB=INT(YA/100):LET BA=2-AB+INT(AB/4)
140 LET JDS=INT(365.25*YA)+INT(30.6001*(MB+1))+INT(DE)+1720994.5#+BA
150 LET TC=(JDS-2415020!)/36525!:REM JDS=2450369;TC=0.9677892
160 LET SD=.276919398#+100.0021359#*TC+1.075E-06*TC*TC
170 LET SD=(SD-INT(SD))*24:LET SD=SD+(DE-INT(DE))*24*1.002737908#
180 IF SD>24 THEN LET SD=SD-24
190 LET LC=SD+(-LONG/15):IF LC>24 THEN LET LC=LC-24
200 IF LC<0 THEN LET LC=LC+24
210 LET HV=(LC-VA)*15:LET WV=HV+LONG:REM SD=13.75688;HV=119.8782
220 LET EV=(SIN(VB/RCN)*SIN(LAT/RCN)+COS(VB/RCN)*COS(LAT/RCN) 
*COS(HV/RCN))
230 LET EV=(ATN(EV/SQR(1-EV*EV)))*RCN :IF EV<0 THEN GOTO 290
250 LET AAV=((SIN(VB/RCN)-SIN(LAT/RCN)*SIN(EV/RCN))/COS(LAT/RCN) 
/COS(EV/RCN))
260 IF ABS(AAV)>.9999 THEN LET AAV=SGN(AAV)*.9999
270 LET AV= (P1/2-ATN(AAV/SQR(1-AAV*AAV)))*RCN
280 IF SIN(HV/RCN)>0 THEN LET AV=360-AV
290 IF EV<0 THEN LOCATE 19,15:PRINT "  OUT    OUT ":GOTO 310
300 LOCATE 19,15:PRINT ;" Az= ";(INT(AV*10))/10;" El=  
";(INT(EV*10))/10
310 END:REM worked example at IHJ QTH gives Az=306.3 and El=3

Do not confuse Surveyor with Mars Pathfinder which launches in Dec 96.
Pathfinder does not use Amateur frequencies, and is taking a different
faster route to Mars.