Satgen 210   Locating Geosats   by GM4IHJ                    3rd April 93
BID of this msg is SGEN210  Please use that BID if you retransmit the msg

Several stations have asked recently about locating geosats , so here is
a brief review.

Each geosat is allocated a position defined as a location above the
equator at a longitude west of Greenwich (+) or east of Greenwich (-) .
Controllers use small fuel powered thrusters to keep them on station,
counteracting the continuous perturbation caused by irregularities in the
earth's gravitational field and, by the pull of the Sun and the Moon.
Geosats should remain within about 1/2 degree of their allocated position
If you know that position , you can work out the azimuth and elevation
bearings on which you need to aim your ground station antenna, in order to
use the satellite. The following BASIC program does the necessary
calculations.

240 LET L=56.113                               : REM Your station latitude
250 LET G=3.575                          : REM your station longitude WEST
260 LET P1 = 3.1415925                               : REM the constant PI
340 INPUT C                         :REM Longitude WEST of geosat location
390 LET L=L*P1/180: LET G=G*P1/180: LET C=C*P1/180    :REM degs to radians
440 LET Z=ABS(C-G)         :REM longitudinal separation geosat and station
450 IF Z>P1 THEN LET Z=ABS(2*P1-Z)         :REM Z cannot exceed PI radians
460 LET D=COS(L)*COS(Z):LET D= - ATN(D/SQR(1-D*D))+P1/2     :REM slant sep
480 IF D>1.41895 THEN GOTO 640             : REM geosat below horizon test
490 LET A=( - SIN(L)*COS(D))/(COS(L)*SIN(D))  :REM start calculate azimuth
500 IF ABS(A)>.9999 THEN LET A=(SGN(A))*.9999      :REM cos overshoot trap
540 LET AZ=( - ATN(A/SQR(1-A*A))+P1/2)*57.3     :REM part 2 az calculation
550 IF C>G AND C<(P1+G) OR C>(2*P1+G) THEN LET AZ=360-AZ :REM get AZ phase
560 LET EL=(P1/2 -(ATN(42171*SIN(D)/(42171*COS(D)-6371))))*57.3    :REM EL
580 PRINT "  AZ  ";AZ;"  EL  ";EL: GOTO 650
640 PRINT "GEOSAT BELOW HORIZON"
650 STOP 

Worked example for test . Enter above values for L and G, and enter -10 
(satellite location 10 degrees east of Greenwich meridian ) at INPUT C  ?
you should get  AZ 163.7939   EL 24.94719 .

SATTV bulletins here on amateur packet regularly report satellite
locations and frequencies. Useful none entertainment signals are rare, but
Mir has used 10835 MHz to relay via Russian geosats grouped over several
degrees around 14 west, 40 east and 90 east locations.

Most people use a fixed dish antenna aimed at one geosat, but you can put
a dish on a "POLAR MOUNT" with its rotation axis tilted to point at the
POLE STAR or its Southern Hemisphere equivalent. Given a powerful drive to
counter wind pressure you can motor drive a polar mount to access geosats
out to nearly 75 degree of longitude either side of your station. Please
remember however, that you may be able to point at a geosat, but that does
not always mean it is putting a strong signal your way from its narrow
spot beam antennas. 73 de GM4IHJ @ GB7SAN